One More Example of Python Generators in Scheme

I've had some spare time at work these past few days waiting for modestly long-running data analysis procedures to complete. Unfortunately, this spare time comes in ~5 min chunks, so it's not really worth a serious context switch into other work-related stuff. So, I've been doing a lot of little things---like web browsing about Python generators in scheme. I'm unable to resist posting my own implementation of generators here. The interesting thing about these (as opposed to the two I've linked to above) is that they allow multiple-value yields. Probably not terribly efficient (I think I could get away with let/ec, for example), but nonetheless fun.

(module generators mzscheme
  (provide define-generator)
  
  (define-syntax define-generator
    (lambda (stx)
      (syntax-case stx ()
        ((define-generator (name arg ...) body0 body1 ...)
         (with-syntax ((yield (datum->syntax-object 
                               (syntax body0) 
                               'yield)))
           (syntax
            (define (name arg ...)
              (letrec ((continue-k #f)
                       (return-k #f)
                       (yield
                        (lambda args
                          (let/cc cont
                            (set! continue-k cont)
                            (call-with-values 
                             (lambda () (apply values args)) 
                             return-k)))))
                (lambda ()
                  (let/cc ret
                    (set! return-k ret)
                    (if continue-k
                        (continue-k '())
                        (begin
                          body0 body1 ...
                          (error 'name "reached end of generator values"))))))))))))))

Examples of use:

> (require generators)
> (define-generator (nums-from n)
    (let loop ((i n))
      (yield i)
      (loop (+ i 1))))
> (define ten-up (nums-from 10))
> (ten-up)
10
> (ten-up)
11
> (ten-up)
12
> (ten-up)
13
> (ten-up)
14

and

> (define-generator (next-two-from n)
    (let loop ((i n))
      (yield i (+ i 1))
      (loop (+ i 2))))
> (define ten-by-twos (next-two-from 10))
> (let-values (((a b)
                (ten-by-twos)))
    (+ a b))
21
> (ten-by-twos)
12
13